%%%-------------------------------------------------------------------
%%% @author anlicheng
%%% @copyright (C) 2025, <COMPANY>
%%% @doc
%%%
%%% @end
%%% Created : 07. 5月 2025 15:47
%%%-------------------------------------------------------------------
-module(docker_deployer).
-author("anlicheng").
-include("efka_tables.hrl").

-behaviour(gen_server).

%% API
-export([start_link/3]).
-export([deploy/1]).
-export([maybe_create_env_file/2]).
-export([test/0]).

%% gen_server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-define(SERVER, ?MODULE).

-record(state, {
    root_dir :: string(),
    task_id :: integer(),
    config = #{}
}).

test() ->
    M = #{
        <<"image">> => <<"docker.1ms.run/library/nginx:latest">>,
        <<"container_name">> => <<"my_nginx">>,
        <<"command">> => [<<"nginx">>,<<"-g">>,<<"daemon off;">>],
        <<"entrypoint">> => [<<"/docker-entrypoint.sh">>],
        <<"envs">> => [<<"ENV1=val1">>, <<"ENV2=val2">>],
        <<"env_file">> => [<<"./env.list">>],
        <<"ports">> => [<<"8080:80">>, <<"443:443">>],
        <<"expose">> => [<<"80">>, <<"443">>],
        <<"volumes">> => [<<"/host/data:/data">>, <<"/host/log:/var/log">>],
        <<"networks">> => [<<"mynet">>],
        <<"labels">> => #{ <<"role">> => <<"web">>, <<"env">> => <<"prod">> },
        <<"restart">> => <<"always">>,
        <<"user">> => <<"www-data">>,
        <<"working_dir">> => <<"/app">>,
        <<"hostname">> => <<"myhost">>,
        <<"privileged">> => true,
        <<"cap_add">> => [<<"NET_ADMIN">>],
        <<"cap_drop">> => [<<"MKNOD">>],
        <<"devices">> => [<<"/dev/snd:/dev/snd">>],
        <<"mem_limit">> => <<"512m">>,
        <<"mem_reservation">> => <<"256m">>,
        <<"cpu_shares">> => 512,
        <<"cpus">> => 1.5,
        <<"ulimits">> => #{ <<"nofile">> => <<"1024:2048">> },
        <<"sysctls">> => #{ <<"net.ipv4.ip_forward">> => <<"1">> },
        <<"tmpfs">> => [<<"/tmp">>],
        <<"extra_hosts">> => [<<"host1:192.168.0.1">>],
        <<"healthcheck">> => #{
            <<"test">> => [<<"CMD-SHELL">>, <<"curl -f http://localhost || exit 1">>],
            <<"interval">> => <<"30s">>,
            <<"timeout">> => <<"10s">>,
            <<"retries">> => 3
        }
    },

    TaskId = 1,
    RootDir = "/tmp/",

    Res = do_deploy(TaskId, RootDir, M),
    lager:debug("res is: ~p", [Res]).

%%%===================================================================
%%% API
%%%===================================================================

-spec deploy(Pid :: pid()) -> no_return().
deploy(Pid) when is_pid(Pid) ->
    gen_server:cast(Pid, deploy).

%% @doc Spawns the server and registers the local name (unique)
-spec(start_link(TaskId :: integer(), ContainerDir :: string(), Config :: map()) ->
    {ok, Pid :: pid()} | ignore | {error, Reason :: term()}).
start_link(TaskId, ContainerDir, Config) when is_integer(TaskId), is_list(ContainerDir), is_map(Config) ->
    gen_server:start_link(?MODULE, [TaskId, ContainerDir, Config], []).

%%%===================================================================
%%% gen_server callbacks
%%%===================================================================

%% @private
%% @doc Initializes the server
-spec(init(Args :: term()) ->
    {ok, State :: #state{}} | {ok, State :: #state{}, timeout() | hibernate} |
    {stop, Reason :: term()} | ignore).
init([TaskId, ContainerDir, Config]) ->
    {ok, #state{task_id = TaskId, root_dir = ContainerDir, config = Config}}.

%% @private
%% @doc Handling call messages
-spec(handle_call(Request :: term(), From :: {pid(), Tag :: term()},
    State :: #state{}) ->
    {reply, Reply :: term(), NewState :: #state{}} |
    {reply, Reply :: term(), NewState :: #state{}, timeout() | hibernate} |
    {noreply, NewState :: #state{}} |
    {noreply, NewState :: #state{}, timeout() | hibernate} |
    {stop, Reason :: term(), Reply :: term(), NewState :: #state{}} |
    {stop, Reason :: term(), NewState :: #state{}}).
handle_call(_Request, _From, State = #state{}) ->
    {reply, ok, State}.

%% @private
%% @doc Handling cast messages
-spec(handle_cast(Request :: term(), State :: #state{}) ->
    {noreply, NewState :: #state{}} |
    {noreply, NewState :: #state{}, timeout() | hibernate} |
    {stop, Reason :: term(), NewState :: #state{}}).
handle_cast(deploy, State = #state{task_id = TaskId, root_dir = RootDir, config = Config}) ->
    do_deploy(TaskId, RootDir, Config),
    {stop, normal, State};
handle_cast(_Request, State) ->
    {stop, normal, State}.

%% @private
%% @doc Handling all non call/cast messages
-spec(handle_info(Info :: timeout() | term(), State :: #state{}) ->
    {noreply, NewState :: #state{}} |
    {noreply, NewState :: #state{}, timeout() | hibernate} |
    {stop, Reason :: term(), NewState :: #state{}}).
handle_info(_Info, State = #state{}) ->
    {noreply, State}.

%% @private
%% @doc This function is called by a gen_server when it is about to
%% terminate. It should be the opposite of Module:init/1 and do any
%% necessary cleaning up. When it returns, the gen_server terminates
%% with Reason. The return value is ignored.
-spec(terminate(Reason :: (normal | shutdown | {shutdown, term()} | term()),
    State :: #state{}) -> term()).
terminate(_Reason, _State = #state{}) ->
    ok.

%% @private
%% @doc Convert process state when code is changed
-spec(code_change(OldVsn :: term() | {down, term()}, State :: #state{},
    Extra :: term()) ->
    {ok, NewState :: #state{}} | {error, Reason :: term()}).
code_change(_OldVsn, State = #state{}, _Extra) ->
    {ok, State}.

%%%===================================================================
%%% Internal functions
%%%===================================================================

%{
%   "image": "nginx:latest",
%   "container_name": "my_nginx",
%   "ports": ["8080:80", "443:443"],
%   "volumes": ["/host/data:/data", "/host/log:/var/log"],
%   "envs": ["ENV1=val1", "ENV2=val2"],
%   "entrypoint": ["/docker-entrypoint.sh"],
%   "command": ["nginx", "-g", "daemon off;"],
%   "restart": "always"
%}
-spec do_deploy(TaskId :: integer(), ContainerDir :: string(), Config :: map()) -> no_return().
do_deploy(TaskId, ContainerDir, Config) when is_integer(TaskId), is_list(ContainerDir), is_map(Config) ->
    %% 尝试拉取镜像
    ContainerName = maps:get(<<"container_name">>, Config),
    efka_remote_agent:task_event_stream(TaskId, <<"开始部署容器:"/utf8, ContainerName/binary>>),

    case docker_commands:check_container_exist(ContainerName) of
        true ->
            efka_remote_agent:task_event_stream(TaskId, <<"本地容器已经存在:"/utf8, ContainerName/binary>>);
        false ->
            Image0 = maps:get(<<"image">>, Config),
            Image = normalize_image(Image0),
            efka_remote_agent:task_event_stream(TaskId, <<"使用镜像:"/utf8, Image/binary>>),

            PullResult = case docker_commands:check_image_exist(Image) of
                             true ->
                                 efka_remote_agent:task_event_stream(TaskId, <<"镜像本地已存在:"/utf8, Image/binary>>),
                                 ok;
                             false ->
                                 efka_remote_agent:task_event_stream(TaskId, <<"开始拉取镜像:"/utf8, Image/binary>>),
                                 CB = fun
                                          ({message, Msg}) ->
                                              efka_remote_agent:task_event_stream(TaskId, Msg);
                                          ({error, Error}) ->
                                              efka_remote_agent:task_event_stream(TaskId, Error)
                                      end,
                                 docker_commands:pull_image(Image, CB)
                         end,

            case PullResult of
                ok ->
                    efka_remote_agent:task_event_stream(TaskId, <<"开始创建容器: "/utf8, ContainerName/binary>>),
                    case docker_commands:create_container(ContainerName, ContainerDir, Config) of
                        {ok, ContainerId} ->
                            %% 创建容器对应的配置文件
                            ConfigFile = docker_container_helper:get_config_file(ContainerDir),
                            case file:open(ConfigFile, [write, exclusive]) of
                                {ok, FD} ->
                                    ok = file:write(FD, <<>>),
                                    file:close(FD);
                                {error, Reason} ->
                                    Reason1 = list_to_binary(io_lib:format("~p", [Reason])),
                                    efka_remote_agent:task_event_stream(TaskId, <<"创建配置文件失败: "/utf8, Reason1/binary>>)
                            end,
                            ShortContainerId = binary:part(ContainerId, 1, 12),
                            efka_remote_agent:task_event_stream(TaskId, <<"容器创建成功: "/utf8, ShortContainerId/binary>>),
                            efka_remote_agent:task_event_stream(TaskId, <<"任务完成"/utf8>>);
                        {error, Reason} ->
                            efka_remote_agent:task_event_stream(TaskId, <<"容器创建失败: "/utf8, Reason/binary>>),
                            efka_remote_agent:task_event_stream(TaskId, <<"任务失败"/utf8>>)
                    end;
                {error, Reason} ->
                    efka_remote_agent:task_event_stream(TaskId, <<"镜像拉取失败: "/utf8, Reason/binary>>)
            end
    end.

maybe_create_env_file(_ContainerDir, []) ->
    ok;
maybe_create_env_file(ContainerDir, Envs) when is_list(Envs)->
    TargetFile = ContainerDir ++ "env",
    {ok, IoDevice} = file:open(TargetFile, [write, binary]),
    lists:foreach(fun(Env) -> file:write(IoDevice, <<Env/binary, $\n>>) end, Envs),
    ok = file:close(IoDevice),
    {ok, TargetFile}.

-spec normalize_image(binary()) -> binary().
normalize_image(Image) when is_binary(Image) ->
    Parts = binary:split(Image, <<"/">>, [global]),
    {PrefixParts, [Last]} = lists:split(length(Parts) - 1, Parts),
    NormalizedLast = case binary:split(Last, <<":">>, [global]) of
                         [_Name] -> <<Last/binary, ":latest">>;
                         [_Name, _Tag] -> Last
                     end,
    iolist_to_binary(lists:join(<<"/">>, PrefixParts ++ [NormalizedLast])).